blob: 66902bfd7503441d800c86696de46ca2c52e27fb (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
// SPDX-FileCopyrightText: Nheko Contributors
//
// SPDX-License-Identifier: GPL-3.0-or-later
import QtQuick 2.5
import QtQuick 2.12
import QtQuick.Controls 2.12
import im.nheko 1.0
Switch {
id: toggleButton
implicitWidth: indicatorItem.width
state: checked ? "on" : "off"
states: [
State {
name: "off"
PropertyChanges {
target: track
border.color: "#767676"
}
PropertyChanges {
target: handle
x: 0
}
},
State {
name: "on"
PropertyChanges {
target: track
border.color: palette.highlight
}
PropertyChanges {
target: handle
x: indicatorItem.width - handle.width
}
}
]
transitions: [
Transition {
to: "off"
reversible: true
ParallelAnimation {
NumberAnimation {
target: handle
property: "x"
duration: 200
easing.type: Easing.InOutQuad
}
ColorAnimation {
target: track
properties: "color,border.color"
duration: 200
}
}
}
]
indicator: Item {
id: indicatorItem
implicitWidth: 48
implicitHeight: 24
y: parent.height / 2 - height / 2
Rectangle {
id: track
height: parent.height * 0.6
radius: height / 2
width: parent.width - height
x: radius
y: parent.height / 2 - height / 2
color: Qt.rgba(border.color.r, border.color.g, border.color.b, 0.6)
}
Rectangle {
id: handle
y: parent.height / 2 - height / 2
width: parent.height * 0.9
height: width
radius: width / 2
color: palette.button
border.color: "#767676"
}
}
}
|
